第四部分：SPIC 噪聲分析介紹

作者：Art Kay，德州儀器 (TI) 高級應用工程師

在本系列的第三部分，我們對簡單的運算放大器電路進行了實際分析。在本部分中，我們將采用所謂 “TINA SPICE” 電路模擬套件來分析運算放大器電路。（您可在 TI 網站 www.ti.com 上通過輸入 TINA 搜索，獲得 TINA SPICE 的免費版 TINA-TI）。TINA SPICE 能夠就 SPICE 套件進行傳統類型的模擬（如 dc、瞬態、頻率域分析、噪聲分析等）。此外，TINA-TI 還配有眾多 TI 模擬宏模型。

在本部分，我們將介紹 TINA 噪聲分析以及如何證明運算放大器的宏模型能準確對噪聲進行建模。重要的是，我們應當了解，有些模型可能不能對噪聲做適當建模。為此，我們可以用一個簡單的測試步驟來加以檢查，并通過用分離噪聲源和通用運算放大器開發自己的模型來解決這一問題。

測試運算放大器噪聲模型的準確性

圖 4.1 顯示了用于確認運算放大器噪聲模型準確性的測試電路。CCV1 是一種流控電壓源，我們用它來將噪聲電流轉換為噪聲電壓。之所以要進行這種轉換，是因為TINA 中的“輸出噪聲分析”需要對噪聲電壓進行嚴格檢查。CCV1 的增益必須如圖所示設為 1，這樣電流就能直接轉換為電壓。運算放大器采用電壓輸出器配置，這樣輸出就能反映輸入噪聲情況。TINA 能夠識別到兩個輸出測量節點 “voltage_noise” 與 “current_noise”，它們用于生成噪聲圖。由于 TINA 需要輸入源才能進行噪聲分析，因此我們添加了信號源 VG1。我們將此信號源配置成正弦曲線，但這對噪聲分析并不重要（見圖 4.2）。

　　　　　　　　圖 4.1：配置噪聲測試電路（設置 CCV1 增益為 1）

　　　　　　　　　　圖 4.2：配置噪聲測試電路（設置信號源 VG1）

隨后，我們可從下來菜單中選擇 “分析\噪聲分析”（ 如圖 4.3 所示），進行噪聲分析，這將生成噪聲分析表。然后輸入需要的起始和終止頻率。該頻率范圍由受測試的運算放大器的規范決定。就本例而言，OPA227 的規范要求頻率范圍為 0.1 Hz～10 kHz，也就是說，這就是適合本例的頻率范圍。隨后，在 “圖表” 項下選擇 “輸出噪聲” 選項，便可針對電路中每個測量節點（儀表）生成不同的頻譜密度曲線。這樣，我們進行分析時，就能獲得兩個頻譜密度曲線圖，一個是針對 “電壓噪聲”節點，另一個則是針對 “電流噪聲” 節點。

　　　　　　　　　　圖 4.3：執行 “噪聲分析” 選項

圖 4.4 顯示了噪聲分析的結果。我們可用一些簡單的方法來將曲線轉換為更有用的形式。首先，我們點擊 “視圖” 菜單下的 “曲線分離”，隨后，再點擊 Y 軸并選擇 “對數” 標度。根據適當范圍設置上下限（四舍五入到 10 的N次冪）。點數調節為 1+Number_of_Decades。在本例中，我們有三個十倍頻程（即100f ～100p），因此，我們需要四點（見圖 4.5）。

　　　　　　　　　圖 4.4：轉變為更有用的格式的簡單方法（曲線分離）

　　　　　　　　圖 4.5：轉變為更有用的格式的簡單方法（變為對數標度）

我們將模擬結果與圖 4.6 中的 OPA227 數據表相比較。請注意，二者幾乎相同。這就是說，OPA227 的 TINA-TI 模型能準確進行噪聲建模。我們對 OPA627 模型也采用與上述相同的步驟，圖 4.7 顯示了測試結果，發現 OPA627 模型沒能通過測試。OPA627 模型的電流噪聲頻譜密度約為 3.5E-21A/rt-Hz，而規范要求則為 2.5E-15A/rt-Hz。此外，模型中的電壓噪聲未體現 l/f 區。下面，我們將為這款運算放大器建模，實現適當的噪聲建模。

　　　　　　　　　　　　　圖 4.6：OPA227 通過建模測試

　　　　　　　　　　　　圖 4.7：OPA627 未通過建模測試

建立自己的噪聲模型

在第二部分中，我們曾介紹過運算放大器噪聲模型，它包括運算放大器、電壓噪聲源和電流噪聲源。我們將用分離噪聲源和通用運算放大器來構建這一噪聲模型。模擬與 Rf 模型 (Analog & Rf models) 公司的Bill Sands為 TI 開發了分離噪聲源。您可從 TI 網站 www.ti.com下載這種噪聲源，只需搜索 “TINA-TI 應用原理圖” 并查找 “噪聲分析”文件夾即可。我們還在附錄 4.1 和 4.2 中給出了“ TINA 宏”列表。

圖 4.8 顯示了用于創建噪聲模型的電路。請注意，這就是我們此前使用的測試電路配置。該電路配置中有一個連接在輸入端之間的電流噪聲源。嚴格地說，實際上有兩個電流噪聲源。不過，我們從產品說明書很難說清楚這些信號源之間的相互關系。而且，在電流反饋放大器中這些信號源的信號幅度不同。我們在以后的文章中將更詳細地探討上述問題。我們將對電路加以定制，以便對 OPA627 的噪聲特點進行適當建模。

?????????????????? 圖 4.8：采用分離噪聲源的運算放大器噪聲模型

首先，我們應配置噪聲電壓源。這只需在噪聲源上右擊并選擇 “進入宏 ”即可（見圖4.9）。進入“宏”后，彈出文本編輯器，為SPICE宏模型給出了源列表。圖 4.10 顯示了應加以編輯的 “.PARAM” 信息，以匹配于數據表。請注意，NLF 是l/f 區中某一點的噪聲頻譜密度（單位為 nV/rt-Hz）。FLW 是選中點的頻率。

　　　　　　　　　　　　　圖 4.9：進入宏以配置噪聲電壓源

　　　　　　　　　　　　　　圖 4.10：輸入 1/f 區數據

隨后，我們應輸入寬帶噪聲頻譜密度，這里要用到 NVR 參數。請注意，由于寬帶噪聲強度就所有頻率而言都是一樣的，因此這里不需要輸入頻率（見圖4.11）。輸入噪聲信息之后，我們必須編輯并關閉 SPICE 文本編輯器。點擊“校驗框”，注意到狀態欄會顯示 “編輯成功” 消息。在 “文件” 菜單下選擇“關閉”，返回原理圖編輯器（見圖 4.12）。

　　　　　　　　　　　　　　　　圖 4.11：輸入寬帶區數據

我們對電流噪聲源也要采取相同步驟。就此示例來說，電流源沒有 1/f 噪聲。這時，寬帶頻譜密度和 1/f “.PARAM” 均設為2.5fA/rt-Hz。1/f 頻率通常設為非常低的頻率，如 0.001Hz （見圖 4.13）。

　　　　　　　　　　　圖 4.12：編輯 “宏” 并 “關閉”

　　　　　　　　　　　　　　圖 4.13：輸入電流噪聲源數據

現在，我們對兩種噪聲源都進行了適當配置，接下來就要編輯通用運算放大器模型中的一些 AC 參數了。具體說來，必須輸入開環增益和主導極點，因為它們會影響放大器的閉環帶寬，反過來閉環帶寬又會影響電路的噪聲特性。開環增益在數據表中通常采用 dB 為單位。我們可用方程式 4.1 將 dB 轉換為線性增益。我們還可用方程式 4.2 來計算 Aol 曲線中的主導極點。例 4.1 就 OPA627 進行了主導極點計算。圖 4.14 給出了主導極點的圖示。

　方程式 4.11

方程式4.1：將 dB 轉化為線性增益

方程式 4.2

方程式4.2：計算主導極點

例 4.1：查找 OPA627 的線性開環增益和主導極點

　　　　　　　　　　　　圖 4.14：增益主導極點與頻率關系圖

下面，我們應編輯通用運算放大器模型，其中包括開環增益和主導極點。只需雙擊運算放大器標志并按下 “類型” 按鈕即可，這將啟動“目錄編輯器”。在“目錄編輯器”中，我們要修改“開環增益”以匹配于我們在例 4.1 中計算所得的結果。圖 4.15概述了相關步驟。

　　　　　　　　　　　　圖 4.15：編輯通用運算放大器

現在，運算放大器的噪聲模型已經構建完畢。圖 4.16 顯示了模型上運行測試的過程及結果。正如我們所期望的那樣，新模型與數據表剛好匹配。

　　　　　　　　圖 4.16：“手工構建的”新模型順利通過模型測試

用 TINA 分析第三部分中的電路

圖 4.17 顯示了采用 Tina SPICE 的 OPA627 建模原理圖。請注意，第四部分討論了通過用分離噪聲源和通用運算放大器開發自己的模型來對噪聲進行適當建模的方法，此外，電阻 Rf 和 R1 匹配于第三部分中的示例電路。

　　　　　　　　　　　　　　圖 4.17：OPA627 電路示例

我們可從下來菜單中選擇 “分析\噪聲分析”，進行 Tina SPICE 噪聲分析，這將生成噪聲分析表。我們可在噪聲分析表上選擇 “輸出噪聲” 和 “總噪聲”選項。“輸出噪聲” 選項將針對所有測試點（即帶儀表的節點）生成噪聲頻譜密度圖。“總噪聲”將生成功率譜密度曲線圖積分結果。我們可通過總噪聲曲線明確電路的均方根輸出噪聲電壓。圖 4.18 顯示了如何執行噪聲分析。

　　　　　　　　　　　　　　　　圖 4.18：運行噪聲分析

圖 4.19 和圖 4.20 顯示了 TINA 噪聲分析的結果。圖 4.19 給出了放大器輸出處的噪聲頻譜密度（即輸出噪聲）。該曲線結合了所有噪聲源，并包括噪聲增益的效果和噪聲帶寬。圖 4.20 顯示了給定帶寬下放大器輸出處的總噪聲。我們也可以求功率頻譜密度曲線的積分（即電壓頻譜密度的平方），從而推導出該曲線。請注意，該曲線在高頻下為常量，即323uVrms。這一結果與第三部分中計算得出的均方根噪聲相匹配（我們計算所得的噪聲為324uV）。還要注意，該噪聲為常量，這是由于運算放大器的帶寬限制使然。

　　　　　　　　　　　　　　　圖 4.19：輸出噪聲圖結果

　　　　　　　　　　　　　　圖 4.20：總噪聲圖結果

本文總結和下文內容提要

在本文中，我們介紹了稱作 TINA SPICE 的電路模擬套件。我們用 TINA 開發了一套簡單的測試步驟來檢查運算放大器模型是否可以準確對噪聲進行建模。在某些情況下，有的模型不能通過測試，因此，我們就用分離噪聲源和通用運算放大器開發出了我們自己的模型。我們還用 TINA 來計算第三部分實際分析中所用的示例電路的噪聲。在第五部分，我們將分析測試噪聲的方法，特別是要對此前章節中的噪聲計算結果進行物理測量。

致謝!

特別感謝以下 TI人員提供的技術意見：
Rod Bert，高級模擬 IC 設計經理；
Bruce Trump，線性產品經理；
Tim Green，應用工程設計經理；
Neil Albaugh，高級應用工程師；
Bill Sands，模擬與 Rf 模型 (Analog & Rf models) 公司技術顧問； http://www.home.earthlink.net/%7ewksands/

參考書目

1.)Robert V. Hogg 與 Elliot A Tanis 共同編著的《概率與統計推斷》，第三版，麥克米蘭出版公司 (Macmillan Publishing Co.) 出版；

2.)C. D. Motchenbacher 與 J. A. Connelly 共同編著的《低噪聲電子系統設計》，Wiley-Interscience Publication 出版。

關于作者：

Arthur Kay是 TI 的高級應用工程師。他專門負責傳感器信號調節器件的支持工作。他于 1993 年畢業于佐治亞理工學院 (Georgia Institute of Technology)，并獲得電子工程碩士學位。

附錄 4.1：電壓噪聲宏

* BEGIN PROG NSE NANO VOLT/RT-HZ
.SUBCKT VNSE 1 2
* BEGIN SETUP OF NOISE GEN - NANOVOLT/RT-HZ
* INPUT THREE VARIABLES
* SET UP VNSE 1/F
* NV/RHZ AT 1/F FREQ
.PARAM NLF=15
* FREQ FOR 1/F VAL
.PARAM FLW=10
* SET UP VNSE FB
* NV/RHZ FLATBAND
.PARAM NVR=4.5
* END USER INPUT
* START CALC VALS
.PARAM GLF={PWR(FLW,0.25)*NLF/1164}
.PARAM RNV={1.184*PWR(NVR,2)}
.MODEL DVN D KF={PWR(FLW,0.5)/1E11} IS=1.0E-16
* END CALC VALS
I1 0 7 10E-3
I2 0 8 10E-3
D1 7 0 DVN
D2 8 0 DVN
E1 3 6 7 8 {GLF}
R1 3 0 1E9
R2 3 0 1E9
R3 3 6 1E9
E2 6 4 5 0 10
R4 5 0 {RNV}
R5 5 0 {RNV}
R6 3 4 1E9
R7 4 0 1E9
E3 1 2 3 4 1
C1 1 0 1E-15
C2 2 0 1E-15
C3 1 2 1E-15
.ENDS
·END PROG NSE NANOV/RT-HZ

附錄 4.2：電流噪聲宏

* BEGIN PROG NSE FEMTO AMP/RT-HZ
.SUBCKT FEMT 1 2
* BEGIN SETUP OF NOISE GEN - FEMPTOAMPS/RT-HZ
* INPUT THREE VARIABLES
* SET UP INSE 1/F
* FA/RHZ AT 1/F FREQ
.PARAM NLFF=2.5
* FREQ FOR 1/F VAL
.PARAM FLWF=0.001
* SET UP INSE FB
* FA/RHZ FLATBAND
.PARAM NVRF=2.5
* END USER INPUT
* START CALC VALS
.PARAM GLFF={PWR(FLWF,0.25)*NLFF/1164}
.PARAM RNVF={1.184*PWR(NVRF,2)}
.MODEL DVNF D KF={PWR(FLWF,0.5)/1E11} IS=1.0E-16
* END CALC VALS
I1 0 7 10E-3
I2 0 8 10E-3
D1 7 0 DVNF
D2 8 0 DVNF
E1 3 6 7 8 {GLFF}
R1 3 0 1E9
R2 3 0 1E9
R3 3 6 1E9
E2 6 4 5 0 10
R4 5 0 {RNVF}
R5 5 0 {RNVF}
R6 3 4 1E9
R7 4 0 1E9
G1 1 2 3 4 1E-6
C1 1 0 1E-15
C2 2 0 1E-15
C3 1 2 1E-15
.ENDS
* END PROG NSE FEMTO AMP/RT-HZ