一、Cmake 簡介

cmake 是一個跨平臺、開源的構建系統。它是一個集軟件構建、測試、打包于一身的軟件。它使用與平臺和編譯器獨立的配置文件來對軟件編譯過程進行控制。

二、常用命令

1. 指定 cmake 的最小版本

cmake_minimum_required(VERSION 3.4.1)

這行命令是可選的，我們可以不寫這句話，但在有些情況下，如果 CMakeLists.txt 文件中使用了一些高版本 cmake 特有的一些命令的時候，就需要加上這樣一行，提醒用戶升級到該版本之后再執行 cmake。

2. 設置項目名稱

project(demo)

這個命令不是強制性的，但最好都加上。它會引入兩個變量 demo_BINARY_DIR 和 demo_SOURCE_DIR，同時，cmake 自動定義了兩個等價的變量 PROJECT_BINARY_DIR 和 PROJECT_SOURCE_DIR。

3. 設置編譯類型

add_executable(demo demo.cpp) # 生成可執行文件

add_library(common STATIC util.cpp) # 生成靜態庫

add_library(common SHARED util.cpp) # 生成動態庫或共享庫

add_library 默認生成是靜態庫，通過以上命令生成文件名字

1.在 Linux 下是：

demo
libcommon.a
libcommon.so

2.在 Windows 下是：

demo.exe
common.lib
common.dll

4. 指定編譯包含的源文件

4.1 明確指定包含哪些源文件

add_library(demo demo.cpp test.cpp util.cpp)

4.2 搜索所有的 cpp 文件

aux_source_directory(dir VAR) 發現一個目錄下所有的源代碼文件并將列表存儲在一個變量中；
aux_source_directory(. SRC_LIST) # 搜索當前目錄下的所有.cpp文件；
add_library(demo ${SRC_LIST})；

4.3 自定義搜索規則

file(GLOB SRC_LIST "*.cpp" "protocol/*.cpp")
add_library(demo ${SRC_LIST})
# 或者
file(GLOB SRC_LIST "*.cpp")
file(GLOB SRC_PROTOCOL_LIST "protocol/*.cpp")
add_library(demo ${SRC_LIST} ${SRC_PROTOCOL_LIST})
# 或者
aux_source_directory(. SRC_LIST)
aux_source_directory(protocol SRC_PROTOCOL_LIST)
add_library(demo ${SRC_LIST} ${SRC_PROTOCOL_LIST})

5. 查找指定的庫文件

find_library(VAR name path)查找到指定的預編譯庫，并將它的路徑存儲在變量中；

默認的搜索路徑為 cmake 包含的系統庫，因此如果是 NDK 的公共庫只需要指定庫的 name 即可；

find_library( # Sets the name of the path variable.
              log-lib
              # Specifies the name of the NDK library that
              # you want CMake to locate.
              log )
類似的命令還有 find_file()、find_path()、find_program()、find_package()

6. 設置包含的目錄

include_directories(
    ${CMAKE_CURRENT_SOURCE_DIR}
    ${CMAKE_CURRENT_BINARY_DIR}
    ${CMAKE_CURRENT_SOURCE_DIR}/include
)

Linux 下還可以通過如下方式設置包含的目錄：

set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -I${CMAKE_CURRENT_SOURCE_DIR}")

7. 設置鏈接庫搜索目錄

link_directories(
    ${CMAKE_CURRENT_SOURCE_DIR}/libs
)

Linux 下還可以通過如下方式設置包含的目錄：

set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -L${CMAKE_CURRENT_SOURCE_DIR}/libs")

8. 設置 target 需要鏈接的庫

target_link_libraries( # 目標庫
                       demo
                       # 目標庫需要鏈接的庫
                       # log-lib 是上面 find_library 指定的變量名
                       ${log-lib} )

在 Windows 下，系統會根據鏈接庫目錄，搜索xxx.lib 文件，Linux 下會搜索 xxx.so 或者 xxx.a 文件，如果都存在會優先鏈接動態庫（so 后綴）

8.1 指定鏈接動態庫或靜態庫

target_link_libraries(demo libface.a) # 鏈接libface.a
target_link_libraries(demo libface.so) # 鏈接libface.so

8.2 指定全路徑

target_link_libraries(demo ${CMAKE_CURRENT_SOURCE_DIR}/libs/libface.a)
target_link_libraries(demo ${CMAKE_CURRENT_SOURCE_DIR}/libs/libface.so)

8.3 指定鏈接多個庫

target_link_libraries(demo
    ${CMAKE_CURRENT_SOURCE_DIR}/libs/libface.a
    boost_system.a
    boost_thread
    pthread)

9. 設置變量

9.1 set 直接設置變量的值

set(SRC_LIST main.cpp test.cpp)
add_executable(demo ${SRC_LIST})

9.2 set 追加設置變量的值

set(SRC_LIST main.cpp)
set(SRC_LIST ${SRC_LIST} test.cpp)
add_executable(demo ${SRC_LIST})

9.3 list 追加或者刪除變量的值

set(SRC_LIST main.cpp)
list(APPEND SRC_LIST test.cpp)
list(REMOVE_ITEM SRC_LIST main.cpp)
add_executable(demo ${SRC_LIST})

10. 條件控制

10.1 if…elseif…else…endif

邏輯判斷和比較：

if (expression)：expression 不為空（0,N,NO,OFF,FALSE,NOTFOUND）時為真
if (not exp)：與上面相反
if (var1 AND var2)
if (var1 OR var2)
if (COMMAND cmd)：如果 cmd 確實是命令并可調用為真
if (EXISTS dir) if (EXISTS file)：如果目錄或文件存在為真
if (file1 IS_NEWER_THAN file2)：當 file1 比 file2 新，或 file1/file2 中有一個不存在時為真，文件名需使用全路徑
if (IS_DIRECTORY dir)：當 dir 是目錄時為真
if (DEFINED var)：如果變量被定義為真
if (var MATCHES regex)：給定的變量或者字符串能夠匹配正則表達式 regex 時為真，此處 var 可以用 var 名，也可以用 ${var}
if (string MATCHES regex)

數字比較：

if (variable LESS number)：LESS 小于
if (string LESS number)
if (variable GREATER number)：GREATER 大于
if (string GREATER number)
if (variable EQUAL number)：EQUAL 等于
if (string EQUAL number)

字母表順序比較：

if (variable STRLESS string)
if (string STRLESS string)
if (variable STRGREATER string)
if (string STRGREATER string)
if (variable STREQUAL string)
if (string STREQUAL string)

示例：

if(MSVC)
    set(LINK_LIBS common)
else()
    set(boost_thread boost_log.a boost_system.a)
endif()
target_link_libraries(demo ${LINK_LIBS})
# 或者
if(UNIX)
    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11 -fpermissive -g")
else()
    add_definitions(-D_SCL_SECURE_NO_WARNINGS
    D_CRT_SECURE_NO_WARNINGS
    -D_WIN32_WINNT=0x601
    -D_WINSOCK_DEPRECATED_NO_WARNINGS)
endif()
if(${CMAKE_BUILD_TYPE} MATCHES "debug")
    ...
else()
    ...
endif()

10.2 while…endwhile

while(condition)
    ...
endwhile()

10.3 foreach…endforeach

foreach(loop_var RANGE start stop [step])
    ...
endforeach(loop_var)

start 表示起始數，stop 表示終止數，step 表示步長，示例：

foreach(i RANGE 1 9 2)
    message(${i})
endforeach(i)
# 輸出：13579

11. 打印信息

message(${PROJECT_SOURCE_DIR})
message("build with debug mode")
message(WARNING "this is warnning message")
message(FATAL_ERROR "this build has many error") # FATAL_ERROR 會導致編譯失敗

12. 包含其它 cmake 文件

include(./common.cmake) # 指定包含文件的全路徑
include(def) # 在搜索路徑中搜索def.cmake文件
set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake) # 設置include的搜索路徑

三、常用變量

1. 預定義變量

PROJECT_SOURCE_DIR：工程的根目錄

PROJECT_BINARY_DIR：運行 cmake 命令的目錄，通常是 ${PROJECT_SOURCE_DIR}/build

PROJECT_NAME：返回通過 project 命令定義的項目名稱

CMAKE_CURRENT_SOURCE_DIR：當前處理的 CMakeLists.txt 所在的路徑

CMAKE_CURRENT_BINARY_DIR：target 編譯目錄

CMAKE_CURRENT_LIST_DIR：CMakeLists.txt 的完整路徑

CMAKE_CURRENT_LIST_LINE：當前所在的行

CMAKE_MODULE_PATH：定義自己的 cmake 模塊所在的路徑，SET(CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)，然后可以用INCLUDE命令來調用自己的模塊

EXECUTABLE_OUTPUT_PATH：重新定義目標二進制可執行文件的存放位置

LIBRARY_OUTPUT_PATH：重新定義目標鏈接庫文件的存放位置

2. 環境變量

使用環境變量：

$ENV{Name}

寫入環境變量：

set(ENV{Name} value) # 這里沒有“$”符號

3. 系統信息

-CMAKE_MAJOR_VERSION：cmake 主版本號，比如 3.4.1 中的 3

-CMAKE_MINOR_VERSION：cmake 次版本號，比如 3.4.1 中的 4

-CMAKE_PATCH_VERSION：cmake 補丁等級，比如 3.4.1 中的 1

-CMAKE_SYSTEM：系統名稱，比如 Linux--2.6.22

-CMAKE_SYSTEM_NAME：不包含版本的系統名，比如 Linux

-CMAKE_SYSTEM_VERSION：系統版本，比如 2.6.22

-CMAKE_SYSTEM_PROCESSOR：處理器名稱，比如 i686

-UNIX：在所有的類 UNIX 平臺下該值為 TRUE，包括 OS X 和 cygwin

-WIN32：在所有的 win32 平臺下該值為 TRUE，包括 cygwin

4. 主要開關選項

BUILD_SHARED_LIBS：這個開關用來控制默認的庫編譯方式，如果不進行設置，使用 add_library 又沒有指定庫類型的情況下，默認編譯生成的庫都是靜態庫。如果 set(BUILD_SHARED_LIBS ON) 后，默認生成的為動態庫

CMAKE_C_FLAGS：設置 C 編譯選項，也可以通過指令 add_definitions() 添加

CMAKE_CXX_FLAGS：設置 C++ 編譯選項，也可以通過指令 add_definitions() 添加

add_definitions(-DENABLE_DEBUG -DABC) # 參數之間用空格分隔

四、項目示例

1. 初試 cmake 的 helloworld

現在新建一個 hello.cpp 源碼文件，代碼如下：

#include 
int main(int argc, char* argv[]){
  printf("Hello CMake!
");
}

之前都是采用 gcc hello.cpp -o hello 命令來生成可執行文件，但現在我們用 CMake 這種方式來生成，新建一個 CMakeLists.txt 文件名大小寫都按照這個來：

# 指定工程名
PROJECT (HELLO)
# 現階段，你只需要了解 SET 指令可以用來顯式的定義變量即可
# 將 hello.cpp 賦值給 SRC_LIST 變量，也可以指定多個源文件，用空格隔開
# SET(SRC_LIST hello.cpp add.cpp sub.cpp)
SET(SRC_LIST hello.cpp)
# 輸出打印構建目錄
MESSAGE(STATUS "This is HELLO_BINARY_DIR " ${HELLO_BINARY_DIR})
# 輸出打印資源目錄
MESSAGE(STATUS "This is HELLO_SOURCE_DIR " ${HELLO_SOURCE_DIR})
# 輸出打印資源目錄，與HELLO_SOURCE_DIR 一樣 
MESSAGE(STATUS "This is PROJECT_SOURCE_DIR " ${PROJECT_SOURCE_DIR})
# 輸出打印 CMake 資源目錄，與 PROJECT_SOURCE_DIR 一樣 
MESSAGE(STATUS "This is CMAKE_SOURCE_DIR " ${CMAKE_SOURCE_DIR})
# 生成可執行文件 hello ，${SRC_LIST}是引用變量，也就是源文件 hello.cpp
ADD_EXECUTABLE(hello ${SRC_LIST})

新建 build 目錄，cd 到 build 目錄下，敲 cmake .. 命令，ls 一下會發現 CMake 幫我們生成了 Makefile 等等一些文件。敲 make 命令生成 hello 可執行文件，ls 文件列表如下：

ubuntu@VM-0-9-ubuntu:~/NDK_Day88/t1/build$ ls

CMakeCache.txt CMakeFiles cmake_install.cmake hello Makefile

2. 構建生成 .so 動態庫

上面的例子看不出有啥優勢，甚至說還不如用 gcc hello.cpp -o hello 來得快，但像 FFmpeg 、OpenCV 等等，類似這樣復雜的項目，我們敲命令去構建項目是很麻煩的。下面我們來講一個稍微復雜一點的例子：

mkdir 新建 3 個目錄分別為 src、libs、include 。src 用來存放源文件 add.ccp、sub.cpp、div.cpp。include 用來存放頭文件 add.h、div.h、sub.h 。源碼如下：

#include "add.h"
int add(int num1, int num2){
        return num1 + num2;
}
#include "sub.h"                         
int sub(int num1, int num2){         
        return num1 - num2;         
}
#include "div.h"                                              
int div(int num1, int num2){                    
        return num1 / num2;                  
}

基于這些準備工作，我們想用 CMake 來構建一個 libmath.so 動態庫，并且將其生成在 libs 目錄文件夾下

# 指定 cmake 最低編譯版本
CMAKE_MINIMUM_REQUIRED(VERSION 3.14)
PROJECT (MATH)
# 把當前工程目錄下的 src 目錄的下的所有 .cpp 和 .c 文件賦值給 SRC_LIST
# AUX_SOURCE_DIRECTORY(${PROJECT_SOURCE_DIR}/src SRC_LIST)
FILE(GLOB SRC_LIST "${PROJECT_SOURCE_DIR}/src/*.cpp")
# 打印 SRC_LIST 文件列表
# MESSAGE(STATUS ${SRC_LIST})
# 指定頭文件目錄
INCLUDE_DIRECTORIES(${PROJECT_SOURCE_DIR}/include)
# 指定輸出 .so 動態庫的目錄位置
SET(LIBRARY_OUTPUT_PATH ${PROJECT_SOURCE_DIR}/lib)
# 指定生成動態庫
ADD_LIBRARY(math SHARED ${SRC_LIST})
# 指定生成版本號，VERSION指代動態庫版本，SOVERSION指代API版本
# SET_TARGET_PROPERTIES(math PROPERTIES VERSION 1.2 SOVERSION 1)

3. 鏈接外部動態庫和頭文件

將 libs 目錄和 include 目錄 copy 到 hello.cpp 同級目錄下，修改 hello.cpp 源碼如下：

#include 
#include "add.h"
#include "sub.h"
#include "div.h"
int main(int argc, char* argv[]){
        int a = 20;
        int b = 10;
        printf("%d+%d=%d
",a,b,add(a,b));
        printf("%d-%d=%d
",a,b,sub(a,b));
        printf("%d/%d=%d
",a,b,div(a,b));
        return 0;
}

現在我引用了 include 目錄下的頭文件，同時需要鏈接 libs 目錄下的 libmath.so ，我們再次創建一個 CMakeLists.txt 來生成可執行文件 hello

# 指定cmake最低編譯版本
CMAKE_MINIMUM_REQUIRED(VERSION 3.14)
# 指定工程的名稱
PROJECT(HELLO)
#指定頭文件目錄位置
INCLUDE_DIRECTORIES(${PROJECT_SOURCE_DIR}/include)
#添加共享庫搜索路徑
LINK_DIRECTORIES(${PROJECT_SOURCE_DIR}/lib)
#生成可執行文件
ADD_EXECUTABLE(hello hello.cpp)
#為hello添加共享庫鏈接
TARGET_LINK_LIBRARIES(hello math)

4. 基于 FFmpeg 開發的 CMakeLists.txt

音視頻的播放，在線直播，音視頻通話開發，后面可能都得基于 FFmpeg 來寫。那么首先我們需要編譯 .so 動態庫，然后把動態庫和頭文件 copy 到 AS 來開發，這里我已經編譯好了一個 3.3.9 的版本，至于怎么寫 shell 編譯腳本，會在下篇文章中介紹。目前大伙先直接拿過來用就行了。我把編譯好的 .so 動態庫和 include 目錄拷貝到 AS 工程的 jniLibs 目錄下

# For more information about using CMake with Android Studio, read the
# documentation: https://d.android.com/studio/projects/add-native-code.html
# Sets the minimum version of CMake required to build the native library.
cmake_minimum_required(VERSION 3.4.1)
# 需要引入我們頭文件,以這個配置的目錄為基準
include_directories(src/main/jniLibs/include)
include_directories(src/main/jniLibs/other)
# Creates and names a library, sets it as either STATIC
# or SHARED, and provides the relative paths to its source code.
# You can define multiple libraries, and CMake builds them for you.
# Gradle automatically packages shared libraries with your APK.
#添加共享庫搜索路徑
LINK_DIRECTORIES(${CMAKE_SOURCE_DIR}/src/main/jniLibs/armeabi)
# 指定源文件目錄
AUX_SOURCE_DIRECTORY(${CMAKE_SOURCE_DIR}/src/main/cpp SRC_LIST)
add_library( 
        # Sets the name of the library.
        native-lib
        # Sets the library as a shared library.
        SHARED
        # Provides a relative path to your source file(s).
        # src/main/cpp/native-lib.cpp
        ${SRC_LIST}
        )
# Searches for a specified prebuilt library and stores the path as a
# variable. Because CMake includes system libraries in the search path by
# default, you only need to specify the name of the public NDK library
# you want to add. CMake verifies that the library exists before
# completing its build.
find_library( # Sets the name of the path variable.
        log-lib
        # Specifies the name of the NDK library that
        # you want CMake to locate.
        log)
# Specifies libraries CMake should link to your target library. You
# can link multiple libraries, such as libraries you define in this
# build script, prebuilt third-party libraries, or system libraries.
target_link_libraries( 
        # Specifies the target library.
        # 鏈接額外的 ffmpeg 的編譯
        native-lib
        # 編解碼(最重要的庫)
        avcodec-57
        # 設備信息
        avdevice-57
        # 濾鏡特效處理庫
        avfilter-6
        # 封裝格式處理庫
        avformat-57
        # 工具庫(大部分庫都需要這個庫的支持)
        avutil-55
        # 后期處理
        postproc-54
        # 音頻采樣數據格式轉換庫
        swresample-2
        # 視頻像素數據格式轉換
        swscale-4
        -landroid
        # Links the target library to the log library
        # included in the NDK.
        ${log-lib})

審核編輯：劉清