CWRITE

CWRITE 將數據寫入打開的串行接口或加載的 LD_EXT_OBJ 類型的外部模塊。在加載的 LD_EXT_FCT 類型的外部模塊中，CWRITE 調用一個函數。

CWRITE 將命令寫入命令通道。

CWRITE 觸發提前運行停止。

CWRITE ( Handle or $CMD, State, Mode, Format, Var1 <, ..., Var10>)

Handle/$CMD

類型：INT

句柄：由 COPEN 傳輸到 WRITE 的變量，用于標識通道

$CMD：用于寫入命令通道的預定義變量

State:Type: STATE_T

自動返回到 WRITE 的狀態

Mode : Type: INT

類型：MODUS_T

寫入模式, 必須初始化模式。

Format: Type: CHAR[]

在將 Var 變量寫入字符串之前轉換它們。必須為每個 Var 變量指定格式.

Var:

其數據寫入字符串的變量。每個語句最多可以有 10 個變量。

寫模式Mode

寫入模式由 MODUS_T 類型的變量確定。MODUS_T 是一個預定義的枚舉類型：

ENUM MODUS_T SYNC, ASYNC, ABS, COND, SEQ 對于 CWRITE，只有 SYNC 和 ASYNC 相關：

SYNC同步

一旦伙伴控制器從接收緩沖區中取出傳輸的數據，則認為該語句已執行。

ASYNC異步

寫入 LD_EXT_FCT 類型的外部模塊時，不允許 ASYNC 模式！

以下適用于所有其他通道：一旦數據到達伙伴控制器的接收緩沖區，則認為該語句已執行。

• 優于 SYNC：程序執行速度更快。

• 與 SYNC 相比的缺點：可能會丟失數據。

其他價值

如果模式具有 SYNC 或 ASYNC 以外的值，則默認在 SYNC 模式下執行寫入。

例如：

CWRITE($CMD,STAT,MODE,"RUN /R1/CELL ()")程序執行CELL程序

$CMD

通過命令通道$ CMD進行通信

CWRITE可以通過命令通道將語句傳輸到程序解釋器。示例：通過RUN啟動程序并使用STOP將其停止。

與命令通道$ CMD通信

命令通道：啟動、停止和取消選擇程序

程序 A6.SRC 將通過命令通道啟動、停止和取消選擇。這是通過 SUB 文件中的以下程序行來完成的。

DECL STATE_T STAT

DECL MODUS_T MODE

MODE=#SYNC

...

;select program A6()

;to start the program the START-button or

;an external start-signal is needed

IF $FLAG[1]==TRUE THEN

CWRITE($CMD,STAT,MODE,"RUN/R1/A6()")運行程序

$FLAG[1]=FALSE

ENDIF

;stop program A6()

IF $FLAG[2]==TRUE THEN

CWRITE($CMD,STAT,MODE,"STOP 1")程序停止

$FLAG[2]=FALSE

ENDIF

;cancel program A6()

IF $FLAG[3]==TRUE THEN

CWRITE($CMD,STAT,MODE,"CANCEL 1") 退出程序

$FLAG[3]=FALSE

ENDIF

轉換示例:

例子1

整數變量 VI 的值以十進制和十六進制 ASCII 表示法傳輸。第一個 CWRITE 語句傳輸字符 123。第二個 CWRITE 語句傳輸字符 7B。

INT VI

VI=123

CWRITE(HANDLE,SW_T,MW_T,"%d",VI)

CWRITE(HANDLE,SW_T,MW_T,"%x",VI)

例子2

整數變量 VI 的值以二進制表示法傳輸：

INT VI

VI=123

CWRITE(HANDLE,SW_T,MW_T,"%r",VI)

例子3

傳輸數組的所有數組元素：

REAL VR[10]

CWRITE(HANDLE,SW_T,MW_T,"%r",VR[])

使用“%r”格式時，系統不會檢查變量或數組元素是否已初始化。為尚未初始化的數組元素傳輸隨機值。

例子4

數組的前五個數組元素以二進制表示法傳輸：

REAL VR[10]

CWRITE(HANDLE,SW_T,MW_T,"%.5r",VR[])

20 個字節以二進制表示法傳輸。

例子5

傳輸直到第一個未初始化元素的所有數組元素：

CHAR VS[100]

CWRITE(HANDLE,SW_T,MW_T,"%s",VS[])

例子6

傳輸前 50 個數組元素：

CHAR VS[100]

CWRITE(HANDLE,SW_T,MW_T,"%s",VS[])

例子7

ENUM 常量的內部值以 ASCII 符號傳輸。對應號碼轉：

DECL ENUM_TYP E

CWRITE(HANDLE,SW_T,MW_T,"%d",E)

例子8

兩個 REAL 值與附加文本一起傳輸：

REAL V1,V2

V1=3.97

V2=-27.3

CWRITE(...,...,...,"value1=%+#07.3f value2=+#06.2f",V1,V2)

傳輸以下數據：

value1=+03.970

value2=-27.30

CWRITE和命令界面

CELL.SRC可通過CWRITE語句和RUN從SPS.SUB程序中選擇。呼叫僅在冷啟動時生效。

CWRITE可以通過命令通道$CMD將語句傳輸到解釋器。除了機器人口譯員和系統提交外，擴展提交也可在多提交模式下用于此目的。

與單一提交模式相比，以下命令的含義發生了變化：

• RUN[口譯員ID]

• STOP[口譯員ID]

• 重置[口譯員ID]

• 取消[口譯員ID]

口譯員ID：

0：所有提交口譯員

1：機器人翻譯

2：系統提交解釋器

3：擴展提交解釋器1

4:擴展提交解釋器2

…

9：擴展提交解釋器7

此外，RUN還擴展了可選元素[>口譯員ID]。 CWRITE ($CMD, STAT, MODE, "RUN/R1/CELL()") 單次提交模式下的行為： 啟動程序CELL（）。由于CELL（）是一個SRC程序，因此它在機器人解釋器中啟動。 多提交模式下的行為： 與單次提交模式相同。該程序行可用于系統提交或擴展提交。 CWRITE ($CMD, STAT, MODE, "RUN/R1/SPS()") 單次提交模式下的行為： 啟動程序SPS（）。由于SPS（）是一個SUB程序，它在系統提交解釋器中啟動（=僅在單次提交模式下提交解釋器）。 多提交模式下的行為： 啟動程序SPS（）。由于SPS（）是SUB程序，它在系統提交解釋器中啟動。

CWRITE ($CMD, STAT, MODE, "STOP 0")

這個程序行只在機器人程序中有意義。 單次提交模式下的行為： 停止系統提交解釋器。 多提交模式下的行為： 停止所有正在運行的提交解釋器。

CWRITE ($CMD, STAT, MODE, "CANCEL 0")

單次提交模式下的行為： 取消選擇系統提交解釋器。 多提交模式下的行為： 取消選擇所有提交的口譯員。 CWRITE ($CMD, STAT, MODE, "RUN/R1/MySubProg() > 5")

在單次提交模式下不允許使用此語句。

多提交模式下的行為： 如果MySubProg（）是SUB程序，它將從擴展的submit 3開始。 該程序行可用于其他提交解釋器或機器人程序。