環境監測對于人類來說至關重要，空氣質量、土壤構成、環境噪音、溫濕度等對我們的農業發展、城市建設、日常生活都會造成影響。以溫濕度為例：溫濕度高低會影響農作物的生長、影響工程建設進度、影響設備運作，如果我們能夠精確地監測溫濕度數據、及時作出調整，就能促進整個行業的高效運行。

基于這樣的需求考慮，“如何搭建一個良好的環境監測系統”成為了我們需要思考的核心問題。

通常來說，搭建一個良好的環境監測系統，最關鍵的是要建立實時的環境監測預警系統，并保存完整的歷史數據。以產品測試行業為例，當環境不利于產品測試時，只有及時預警，才能采取有效措施調節室內環境，從而避免監測系統損壞。同時也可以根據保存下來的實時數據進行具體分析。

由此可以知道，我們需要的是一套傳輸距離遠、功耗低、還能實時保存數據的環境監測系統。

基于瑞科慧聯（RAK）的模塊化產品 WisBlock 以及軟件平臺 RUI 3 搭建出來的 LoRaWAN?無線環境監測預警系統，恰好符合這一點。WisBlock + RUI3 的環境監測預警系統可以做到全天 24 小時全面準確地進行環境監測。該系統也被廣泛地應用在實驗室溫濕度環境監測、辦公區環境監測、商超冰柜溫度監測、農場大棚溫濕度檢測等多個領域。

今天我就帶大家一起學習快速地搭建這套 LoRa?無線溫濕度監測系統。

搭建前的準備

硬件準備

• WisBlock Base（本示例使用 RAK5005-O）
• WisBlock Core（本示例使用 RAK4631）
• WisBlock Sensor（本示例使用 RAK1906）
• LoRa?天線（本示例使用 CN470頻段）
• 網關（本示例使用 RAK7268網關）

注意：要保持網關與傳感器所屬的頻段相同，本案例我使用的頻段均為 CN470。

軟件準備

• Arduino IDE
• RAK4631 BSP
• Adafruit BME680 庫
• SX126x-Arduino 庫
• 注冊好 Gateway的 TTN賬戶
• DataCake賬戶

硬件安裝

1. 將 LoRa?天線接口對準并放置在 RAK4631 模塊的 LoRa?天線接口搭接處，輕輕按壓 LoRa?天線接口，完成安裝。
2. 將 RAK4631 模塊上的連接器插頭對準 RAK5005-O CUP 插槽上的連接器插座。保持連接器間平行，并將其輕放在插座連接器相應的搭接處。
3. 將傳感器模塊 RAK1906 上的連接器插頭對準 RAK5005-O 插槽的連接器插座。保持連接器間平行，將其輕放在插座連接器相應的搭接處。
4. 組裝過程示意圖如下：

軟件配置

在 Arduino IDE中添加 RAK4631-R 開發板

1、打開 Arduino IDE，進入“文件 > 首選項”

打開 Arduino IDE

2、單擊圖中圖標，修改“附加開發板管理器網址”選項，將 RAK4631-R WisBlock Core 添加中 Arduino 開發板管理器中。

在 Arduino IDE上修改“附加開發板管理器網址”

3、現在復制下方 URL并粘貼至下圖所示區域。如果已存在其他鏈接，將上述鏈接粘貼至新的一行。完成后，單擊“好”。

https://raw.githubusercontent.com/RAKWireless/RAKwireless-Arduino-BSP-Index/main/package_rakwireless.com_rui_index.json?

在Arduino IDE上粘貼復制好的URL

4、重啟 Arduino IDE。進入“工具 > 開發板：“RAK4631” > 開發板管理器”。

重啟Arduino IDE并執行操作

5、在搜索框中輸入“RAK”，窗口會自動出現可用的 RAKwireless WisBlock Core Boards，選擇“RAKwireless RUI nRF Boards”并安裝。

選擇并安裝 RAKwireless RUI nRF Boards

6、BSP 安裝完成后，根據圖中路徑選擇 RAKwireless WisBlock Core模塊。

選擇 RAKwireless WisBlock Core 模塊

7、代碼燒錄

/**
   @file Environment_Monitoring ino
   @author rakwireless com
   @brief This sketch demonstrate how to get environment data from BME680
      and send the data to lora gateway 
   @version 0 1
   @date 2020-07-28
   @copyright Copyright (c) 2020
**/
#include 
#include 
#include  // Click to install library: http://librarymanager/All#Adafruit_BME680

Adafruit_BME680 bme;
/*************************************

   LoRaWAN band setting:
     RAK_REGION_EU433
     RAK_REGION_CN470
     RAK_REGION_RU864
     RAK_REGION_IN865
     RAK_REGION_EU868
     RAK_REGION_US915
     RAK_REGION_AU915
     RAK_REGION_KR920
     RAK_REGION_AS923

 *************************************/
#define OTAA_BAND     (RAK_REGION_CN470)
#define OTAA_DEVEUI   {0x20, 0x17, 0x06, 0x15, 0x0E, 0x00, 0x00, 0x15}
#define OTAA_APPEUI   {0x20, 0x17, 0x06, 0x00, 0x00, 0x00, 0x00, 0x00}
#define OTAA_APPKEY   {0x11, 0x22, 0x33, 0x44, 0x55, 0x66, 0x77, 0x88, 0x99, 0x00, 0xAA, 0xBB, 0xCC, 0xDD, 0xEE, 0xFF}


// Might need adjustments
#define SEALEVELPRESSURE_HPA (1010.0)
uint8_t buffer[13]="";

void bme680_get()
{
  Serial.print("Temperature = ");
  Serial.print(bme.temperature);
  Serial.println(" C");

  Serial.print("Pressure = ");
  Serial.print(bme.pressure / 100.0);
  Serial.println(" hPa");

  Serial.print("Humidity = ");
  Serial.print(bme.humidity);
  Serial.println(" %");

  Serial.print("Gas = ");
  Serial.print(bme.gas_resistance / 1000.0);
  Serial.println(" KOhms");

  Serial.println();


  uint16_t t = bme.temperature * 100;
  uint32_t pre = bme.pressure / 100.0 * 100;
  uint16_t h = bme.humidity * 100;
  uint32_t gas = bme.gas_resistance;
  
  uint32_t i = 0;
  //result: T=28.25C, RH=50.00%, P=958.57hPa, G=100406 Ohms
   buffer[i++] = 0x01;
   buffer[i++] = (uint8_t)(t >> 8);
   buffer[i++] = (uint8_t)t;
   buffer[i++] = (uint8_t)(h >> 8);
   buffer[i++] = (uint8_t)h;
   buffer[i++] = (uint8_t)((pre & 0xFF000000) >> 24);
   buffer[i++] = (uint8_t)((pre & 0x00FF0000) >> 16);
   buffer[i++] = (uint8_t)((pre & 0x0000FF00) >> 8);
   buffer[i++] = (uint8_t)(pre & 0x000000FF);
   buffer[i++] = (uint8_t)((gas & 0xFF000000) >> 24);
   buffer[i++] = (uint8_t)((gas & 0x00FF0000) >> 16);
   buffer[i++] = (uint8_t)((gas & 0x0000FF00) >> 8);
   buffer[i++] = (uint8_t)(gas & 0x000000FF);
    /** Send the data package */
  if (api.lorawan.send(sizeof(buffer), (uint8_t *)buffer, 2, true, 1))
  {
    Serial.println("Sending is requested");
  } 
  else 
  {
    Serial.println("Sending failed");
  }
}
void init_bme680()
{
  Wire.begin();

  if (!bme.begin(0x76)) {
    Serial.println("Could not find a valid BME680 sensor, check wiring!");
    return;
  }

  // Set up oversampling and filter initialization
  bme.setTemperatureOversampling(BME680_OS_8X);
  bme.setHumidityOversampling(BME680_OS_2X);
  bme.setPressureOversampling(BME680_OS_4X);
  bme.setIIRFilterSize(BME680_FILTER_SIZE_3);
  bme.setGasHeater(320, 150); // 320*C for 150 ms
}
void lora_init()
{
  // OTAA Device EUI MSB first
  uint8_t node_device_eui[8] = OTAA_DEVEUI;
  // OTAA Application EUI MSB first
  uint8_t node_app_eui[8] = OTAA_APPEUI;
  // OTAA Application Key MSB first
  uint8_t node_app_key[16] = OTAA_APPKEY;
  
  if (!api.lorawan.appeui.set(node_app_eui, 8)) {
    Serial.printf("LoRaWan OTAA - set application EUI is incorrect! \r\n");
    return;
  }
  if (!api.lorawan.appkey.set(node_app_key, 16)) {
    Serial.printf("LoRaWan OTAA - set application key is incorrect! \r\n");
    return;
  }
  if (!api.lorawan.deui.set(node_device_eui, 8)) {
    Serial.printf("LoRaWan OTAA - set device EUI is incorrect! \r\n");
    return;
  }
  
  if (!api.lorawan.band.set(OTAA_BAND)) {
    Serial.printf("LoRaWan OTAA - set band is incorrect! \r\n");
    return;
  }
  if (!api.lorawan.deviceClass.set(RAK_LORA_CLASS_A)) {
    Serial.printf("LoRaWan OTAA - set device class is incorrect! \r\n");
    return;
  }
  if (!api.lorawan.njm.set(RAK_LORA_OTAA))  // Set the network join mode to OTAA
  {
    Serial.printf
  ("LoRaWan OTAA - set network join mode is incorrect! \r\n");
    return;
  }
  if (!api.lorawan.join())  // Join to Gateway
  {
    Serial.printf("LoRaWan OTAA - join fail! \r\n");
    return;
  }
  
  /** Wait for Join success */
  while (api.lorawan.njs.get() == 0) {
    Serial.print("Wait for LoRaWAN join...");
    api.lorawan.join();
    delay(10000);
  }
  
  if (!api.lorawan.adr.set(true)) {
    Serial.printf
  ("LoRaWan OTAA - set adaptive data rate is incorrect! \r\n");
    return;
  }
  if (!api.lorawan.rety.set(1)) {
    Serial.printf("LoRaWan OTAA - set retry times is incorrect! \r\n");
    return;
  }
  if (!api.lorawan.cfm.set(1)) {
    Serial.printf("LoRaWan OTAA - set confirm mode is incorrect! \r\n");
    return;
  }
  
  /** Check LoRaWan Status*/
  Serial.printf("Duty cycle is %s\r\n", api.lorawan.dcs.get()? "ON" : "OFF"); // Check Duty Cycle status
  Serial.printf("Packet is %s\r\n", api.lorawan.cfm.get()? "CONFIRMED" : "UNCONFIRMED");  // Check Confirm status
  uint8_t assigned_dev_addr[4] = { 0 };
  api.lorawan.daddr.get(assigned_dev_addr, 4);
  Serial.printf("Device Address is %02X%02X%02X%02X\r\n", assigned_dev_addr[0], assigned_dev_addr[1], assigned_dev_addr[2], assigned_dev_addr[3]);  // Check Device Address
  Serial.println("");

}


void setup()
{
  //Initialize the built in LED
  pinMode(LED_BUILTIN, OUTPUT);
  digitalWrite(LED_BUILTIN, LOW);
  // Initialize Serial for debug output
  Serial.begin(115200);
  time_t serial_timeout = millis();
  while (!Serial)
  {
    if ((millis() - serial_timeout) < 5000)
    {
      delay(100);
      digitalWrite(LED_BUILTIN, !digitalRead(LED_BUILTIN));
    }
    else
    {
      break;
    }
  }
  delay(1000);
  Serial.println("=====================================");
  Serial.println("Welcome to RAK4630 LoRaWan!!!");
  lora_init();
  init_bme680();

} 



void loop()
{
  if (! bme.performReading()) {
    Serial.println("Failed to perform reading :(");
    return;
  }
  bme680_get();
  delay(10000);
}

連接傳感器節點至 TTN

本節為將傳感器節點連接至 TTN（The Things Network）平臺的操作過程。

登錄到 TTN 平臺

登錄TTN網站，將會看到以下頁面：

TTN 網站的控制臺頁面

創建新的應用程序

進入添加 Application 界面，注冊相關信息后，單擊頁面底部的“Create application”。

添加應用

進入應用程序概述頁面，單擊右下角“Add end devices”，在 TTN平臺注冊新設備。

應用程序概述頁面

注冊新設備

在“Register end device”頁面中，單擊“Manually”頁簽。

配置 Frequency plan、LoRaWAN version、Regional Parameters version，并添加設備 DevEUI、AppEUI、AppKey。

注冊設備

設備頻段應與網關頻段相同。

DevEUI、AppEUI、AppKey請在傳感器示例代碼中獲取，切記需要刪除各個數字前的“0x”以及“，”。

獲取 DevEUI、AppEUI、AppKey

單擊"Register and device"，完成設備注冊，注冊結果將匯總如下圖所示。

設備信息

重啟設備后，設備自動入網并定時向服務器傳輸實時監測數據。單擊See all activity→，查看傳輸數據。

環境監測數據獲取

添加 Datacake集成到 TTN

具體可參考：https://docs.datacake.de/lorawan/lns/thethingsindustries

在 Datacake中配置設備

在這里，我假設已經設置 Datacake帳戶，創建好了應用程序，并準備添加設備。如果大家沒有創建好賬戶，可以通過Datacake 文檔了解創建步驟。

在 Datacake 應用程序中，單擊“設備”以查看設備的概述。單擊“添加設備”按鈕開始。

在下一個屏幕中，選擇LoRaWAN New device并點擊“Next”

選擇New product并寫入Product Name

然后，向下滾動窗口，直到看到該部分。在此處選擇“TTN V3”，選擇它，然后單擊“下一步”按鈕。

在下一步中，我們必須輸入節點的 Dev EUI 和名稱。Dev EUI 必須與之前在 TTN V3應用程序中選擇的節點匹配。輸入信息后，再次點擊“下一步”按鈕。

根據我們在 Datacake上的帳戶，以及已經注冊的設備數量，在不同的支付選項之間進行選擇。完成此處選擇后，按“添加1個設備”按鈕。

現在，可以在 Datacake的概述屏幕中看到新設備。

在 Datacake 中為傳感器節點創建數據解析器和數據字段

要完成設備的配置，請在概述中單擊它。在下一個窗口中，選擇 。Configuration

在配置中，向下滾動，直到看到該部分。在這里，必須要輸入我們的自定義有效負載解碼器才能獲取到達的數據。正如圖中所示，解碼器返回一個嵌套的 JSON 數組，其中每個 JSON 條目都有兩個字段。之后會轉發到可視化界面，就能讓傳感器進行數據傳輸了。Payload Decoderfieldvaluefieldvalue

為了使事情變得更容易，我準備了一個有效負載解碼器，它將會與此示例配合使用，而且它也可以輕松擴展與我們其他的WisBlock 解決方案一起使用。

為了節省時間，我將代碼放在這里。使用以下內容覆蓋示例負載解碼器：

function Decoder(payload, port) {
if(payload[0] === 0x01) {
return [
{
field: "TEMPERATURE",
value: (payload[1] << 8 | payload[2]) / 100
},
{
field: "HUMIDITY",
value: (payload[3] << 8 | + payload[4]) / 100
},
{
field: "PRESSURE",
value: (payload[8] | (payload[7] << 8) | (payload[6] << 16) | (payload[5] << 24)) / 100
},
{
field: "GAS",
value: payload[12] | (payload[11] << 8) | (payload[10] << 16) | (payload[9] << 24)
},
];
}
}

現在，我們檢查解碼器是否正常工作。向下滾動并點擊“保存”按鈕以更新解碼器。

然后，一直向上滾動并選擇選項卡。如果此時設備處于聯機狀態并且已發送數據，那么就可以 .DebugDebug Log。

如果這有效，接下來就要做更多的工作了。Datacake 使用字段為可視化查找正確的數據，但必須要先定義所有字段。

返回到配置選項卡并向下滾動，直到看到該部分。到達那里后，單擊添加字段按鈕。Fields

在窗口中，選擇數據類型、字段名稱和單位。Add Field

注意：這里必須與負載解碼器中分配的字段名稱匹配。因此，對于“溫度”，正確的字段名稱是“溫度”。Identifier。

輸入所有信息后，點擊“添加字段”按鈕。

必須重復此步驟，直到定義了將包含傳感器數據的所有四個字段。最后，應該如下所示：Fields

到這里，我們就完成所有的準備工作。現在，我們用一些漂亮的圖表來顯示數據。

設置儀表板以可視化傳入的傳感器數據

返回設備概述并打開選項卡。目前，它是空的。需要添加新的微件，單擊右側的小編輯圖標。Dashboard

現在，我們會看到一個添加小部件按鈕。單擊它開始。

在下一個屏幕中，會看到一系列不同的可視化選項。我選擇了這里。Chart

下一個窗口有四個選項卡。從選項卡開始。就可以在此處輸入圖表標題。Basic

在Field選項卡中，選擇Temperature

現在，它將顯示帶有溫度數據的第一個小部件。我們可以使用微件右下角的小箭頭調整大小。

對其他字段重復這些步驟后，就可以看到包含接收數據的圖表。主要要單擊旁邊的黃色圖標保存你的操作，然后返回主儀表板視圖。HumidityPressureAir QualityUnsaved changes

現在，來自環境傳感器的數據以一個很好的可視化效果呈現出來了，我們可以從任何地方訪問和查看。

添加Rules

這里我們可以對由設備測量值引起的事件執行操作。它們允許設置不同的觸發器和警報，例如：

1、通過電子郵件或短信發送通知消息

2、通過網絡掛鉤調用外部服務

3、將下行鏈路發送到 LoRa?設備

這里可以從工作區的側邊欄菜單創建和訪問規則。與設備相關的規則（一個或多個條件引用設備）還會顯示在設備的“規則”選項卡中。

通過單擊右上角的“添加規則”按鈕創建第一個規則。

我們在這里通過設置溫度的告警值通過郵件的方式提醒

當溫度高于 26℃ 時，Datacake將會通過郵件的方式通知，而且顯示當前的溫度

希望這個教程能夠對大家有所幫助，如果大家有任何問題，也可以留言告訴我們。