reset_primary函數的執行

以CONFIG_BOOT_SYNC_CPU使能為例， 在使能PSCI系統中，不需要使能此宏 。

reset_primary函數執行流程

reset_primary函數是OP-TEE對CPU主核進行初始化操作的函數，該函數會初始化系統的MMU，并調用generic_boot_init_primary函數完成OP-TEE運行環境的建立， 然后觸發sev操作來喚醒從核 ， 待所有CPU核都啟動完成之后 ，OP-TEE會觸發安全監控模式調用（smc）， 通知系統OP-TEE啟動已完成并將CPU的狀態切換回到正常世界狀態 ，該函數的執行流程如圖所示。

reset_primary函數的主要代碼內容如下：

LOCAL_FUNC reset_primary , :
    UNWIND( .fnstart)
    UNWIND( .cantunwind)
        /＊ 清空BSS段 ＊/
        ldr r0, =__bss_start
        ldr r1, =__bss_end
        mov r2, #0
        mov r3, #0
    clear_bss:
        stmia    r0! , {r2, r3}
        cmp r0, r1
        bls clear_bss
    /＊ 初始化內存shadow區域，并設定權限 ＊/
    #ifdef CFG_CORE_SANITIZE_KADDRESS
        ldr r0, =__asan_shadow_start
        ldr r1, =__asan_shadow_end
        mov r2, #ASAN_DATA_RED_ZONE
    shadow_no_access:
        str r2, [r0], #4
        cmp r0, r1
        bls shadow_no_access
        /＊ 標記整個棧區域準備完成 ＊/
        ldr r2, =CFG_ASAN_SHADOW_OFFSET
        ldr r0, =__nozi_stack_start
        lsr r0, r0, #ASAN_BLOCK_SHIFT
        add r0, r0, r2
        ldr r1, =__nozi_stack_end
        lsr r1, r1, #ASAN_BLOCK_SHIFT
        add r1, r1, r2
        mov r2, #0
    shadow_stack_access_ok:
        strb     r2, [r0], #1
        cmp r0, r1
        bls shadow_stack_access_ok
    #endif
        set_sp                                       //設定sp寄存器
        bl  plat_cpu_reset_late //core的后期初始化，可根據具體情況執行特定操作
        bl  console_init                            //初始化log數據
        inval_cache_vrange(__text_start, __end) //在初始化階段禁止數據cache
        bl  core_init_mmu_map                      //初始化MMU頁表
        bl  core_init_mmu_regs                     //將MMU頁表信息寫入MMU的TTBRx寄存器中
        bl  cpu_mmu_enable                         //使能MMU
        bl  cpu_mmu_enable_icache                 //使能MMU的指令cache
        bl  cpu_mmu_enable_dcache                 //使能MMU的數據cache
        mov r0, r4                                   /＊ 頁表區域的地址 ＊/
        mov r1, r5                                   /＊ 非安全入口地址 ＊/
        mov r2, r6                                   /＊ 設備樹地址 ＊/
        //帶入paged_table、Linux內核的地址、設備樹信息進入OP-TEE系統運行環境的建立
        bl  generic_boot_init_primary
              mov r4, r0
              flush_cache_vrange(__text_start, __end) //刷新cache
              cpu_is_ready                                //設定CPU主核已經ready
              flush_cpu_semaphores                       //刷新信號量通知從核啟動
              wait_secondary                              //等待從核啟動完成
              bl  thread_clr_boot_thread                //清空系統各thread的狀態
          #if defined(CFG_WITH_ARM_TRUSTED_FW)
              mov r1, r4  //如果支持ATF，則將OP-TEE的handle返回給ATF
          #else
              mov r4, #0
              mov r3, r6
              mov r2, r7
              mov r1, #0
          #endif /＊ CFG_WITH_ARM_TRUSTED_FW ＊/
              mov r0, #TEESMC_OPTEED_RETURN_ENTRY_DONE     //設定返回給Normal World的值
              smc #0  //調用SMC操作切回到Normal World狀態，OP-TEE啟動結束
              b    .    /＊ SMC should not return ＊/
          UNWIND( .fnend)
          END_FUNC reset_primary