在運動控制中，軌跡執(zhí)行時間的預測對于多軸的協(xié)同、路徑預處理等方面有著重要的作用。CODESYS系列控制器提供了預測軌跡執(zhí)行時間功能塊。要實現(xiàn)完整的預測功能，需要使用到以下的功能塊。

SMC_SetForecast

這個功能塊專門用于為指定軸設(shè)定預測，其預測時長被限定在最多512個任務(wù)周期。通過這種預測設(shè)置，用戶能夠預先獲取軸在未來特定時間點的狀態(tài)信息，包括：

持續(xù)時間預測：利用SMC_GetTravelTime功能，可以計算出軸到達某一特定位置所需的時間。

動態(tài)信息獲取：通過SMC_ReadSetValues，能夠在特定時間點獲取軸的動態(tài)信息。

預測時長查詢：使用SMC_GetForecast可以讀取當前的預測時長。

SMC_GetForecast

該功能塊返回給定軸的預測時間，是由SMC_SetForecast 功能塊設(shè)置的。

SMC_GetTravelTime

此功能塊能夠預測軸到達指定位置所需的時間。

要獲取有效的時間預測，需要先通過SMC_SetForecast設(shè)置預測持續(xù)時間，確保軸在預測時間內(nèi)能到達指定位置。如果軸沒有移動，即使它正好在指定位置，Valid也會顯示為FALSE。

SMC_ReadSetValues

該功能塊用于讀取軸的設(shè)定位置、速度、加速度和加加速度。允許設(shè)置一個正的時間偏移量（TimeOffset），以讀取未來的設(shè)定值。當時間偏移量（TimeOffset）= 0時，將讀取當前周期開始時的設(shè)定值。

程序示例

CASE state OF
STATE_POWER_DRIVE:    //軸使能
  mcp.Enable := TRUE;
  mcp.bDriveStart := TRUE;
  mcp.bRegulatorOn := TRUE;


  IF mcp.Status THEN
    state := STATE_SET_FORECAST;
  ELSIF mcp.Error THEN
    error := mcp.ErrorID;
    state := state + STATE_ERROR;  
  END_IF


STATE_SET_FORECAST:    //設(shè)置軌跡預測時長
  setForecast.Execute := TRUE;
  setForecast.ForecastDuration := 0.3;  //0.3S


  getForecast.Enable := TRUE;


  IF setForecast.Done THEN
    state := STATE_MOVE_TO_POSITION;
  ELSIF setForecast.Error THEN
    error := setForecast.ErrorID;
    state := state + STATE_ERROR;  
  END_IF


STATE_MOVE_TO_POSITION:    //MC_MoveAbsolute
  ma.Execute := TRUE;
  ma.Position := 10;
  ma.Velocity := 20;
  ma.Acceleration := 200;
  ma.Deceleration := 200;
  ma.Jerk := 1000;


  timeToPosition.Enable := TRUE;
  timeToPosition.Position := 8;  //預測到達8時，所用的時間


  IF ma.Error THEN
    error := ma.ErrorID;
    state := state + STATE_ERROR;  
  END_IF
END_CASE


setForecast(Axis:= Drive);
getForecast(Axis:= Drive);


mcp(Axis:= Drive);
ma(Axis:= Drive);


timeToPosition(Axis:= Drive);
readSetValues(
  Axis:= Drive, 
  Enable:= timeToPosition.Valid, 
TimeOffset:=timeToPosition.Duration);

可通過采集到的波形圖觀察對于軌跡預測的效果。